# Maintainer: Jaroslav Lichtblau <dragonlord@aur.archlinux.org>
# Contributor: Allan McRae <allan@archlinux.org>
# Contributor: geekitus

pkgname=blobwars
pkgver=2.00
pkgrel=3
pkgdesc="Platform action game featuring a blob wih lot of weapons"
arch=('x86_64')
url="http://sourceforge.net/projects/blobwars"
license=('GPL')
makedepends=('sdl2_image' 'sdl2_mixer' 'sdl2_ttf' 'sdl2_net')
source=(http://downloads.sourceforge.net/project/$pkgname/$pkgname-$pkgver.tar.gz)
md5sums=('73baa49a41151140818cf14cb77d57b4')

prepare() {
  cd "${srcdir}/${pkgname}-${pkgver}"

  # use install instead of mkdir/cp
  sed -i -e 's/mkdir -p/install -dm755/g' \
    -e 's/cp -pr/cp -r/g' \
    -e 's/cp -p /install -m644 /g' Makefile
  # Don't use -Werror
  sed -e 's|-Werror||' -i Makefile
}

build() {
  cd "${srcdir}/${pkgname}-${pkgver}"

  make RELEASE=1
}

package() {
  depends=('hicolor-icon-theme' 'sdl2_image' 'sdl2_mixer' 'sdl2_ttf' 'sdl2_net' 'blobwars-data>=2.0')

  cd "${srcdir}/${pkgname}-${pkgver}"

  make DESTDIR=${pkgdir} BINDIR="/usr/bin/" install

  # We remove data files (See blobwars-data)
  rm -r "${pkgdir}/usr/share/games"

  # namcap: does not have the world readable bit set.
  #chmod 644 "${pkgdir}"/usr/share/doc/blobwars/*
  #chmod 644 "${pkgdir}"/usr/share/icons/hicolor/{16x16,32x32,48x48,64x64}/apps/*
  #chmod 644 "${pkgdir}"/usr/share/applications/blobwars.desktop

  #chmod a+r "${pkgdir}/usr/share/applications/${pkgname}.desktop"
  #chmod a+r -R "${pkgdir}/usr/share/icons/hicolor/"
  #install -dm755 "${pkgdir}/usr/share/pixmaps"
  #install -m644 icons/blobwars.png "${pkgdir}/usr/share/pixmaps/"
}

