# $Id: PKGBUILD 260760 2017-09-28 10:56:11Z jgc $
# Maintainer: Balló György <ballogyor+arch at gmail dot com>
# Contributor: Ionut Biru <ibiru@archlinux.org>
# Contributor: Roman Kyrylych <roman@archlinux.org>
# Contributor: Tor Krill <tor@krill.nu>

pkgname=filemanager-actions
pkgver=3.4
pkgrel=2
pkgdesc="File-manager extension which offers user configurable context menu actions"
arch=('i686' 'x86_64')
url="https://git.gnome.org/browse/filemanager-actions"
license=('GPL')
depends=('gtk3' 'libgtop')
makedepends=('gnome-doc-utils' 'intltool' 'caja' 'libnautilus-extension' 'nemo')
optdepends=('caja: supported file manager'
            'nautilus: supported file manager'
            'nemo: supported file manager')
replaces=('caja-actions' 'caja-actions-gtk3' 'nautilus-actions')
source=(https://download.gnome.org/sources/$pkgname/$pkgver/$pkgname-$pkgver.tar.xz)
sha256sums=('10189781af90df4c99fde0fe98eacd2e12f4577eff5dc9b769618d980668a997')

build() {
  cd $pkgname-$pkgver
  ./configure --prefix=/usr --sysconfdir=/etc --localstatedir=/var --libexecdir=/usr/lib
  sed -i -e 's/ -shared / -Wl,-O1,--as-needed\0/g' libtool
  make
}

package(){
  cd $pkgname-$pkgver
  make DESTDIR="$pkgdir" install
}
