# Maintainer: Antonio Rojas <arojas@archlinux.org>

pkgbase=fpylll
pkgname=(python-fpylll python2-fpylll)
pkgver=0.4.1dev
pkgrel=2
pkgdesc="A Python interface for fplll"
arch=(x86_64)
url="https://github.com/fplll/fpylll"
license=(GPL2)
makedepends=(fplll python-numpy python-cysignals cython python2-numpy python2-cysignals cython2)
source=("https://github.com/fplll/fpylll/releases/download/$pkgver/$pkgbase-$pkgver.tar.gz")
sha256sums=('b2024cb3b03ebd2ca64f4ccea1a38110dc51d38ff62ad720de598ef23946a7eb')

prepare() {
  cp -r $pkgbase-$pkgver{,-py2}
}

build() {
  cd $pkgbase-$pkgver
  python setup.py build

  cd "$srcdir"/$pkgbase-$pkgver-py2
  python2 setup.py build
}

package_python-fpylll() {
  depends=(fplll python-numpy python-cysignals)

  cd $pkgbase-$pkgver
  python setup.py install --skip-build --root="$pkgdir" --optimize=1
}

package_python2-fpylll() {
  depends=(fplll python2-numpy python2-cysignals)
  optdepends=('sagemath: use Sage integers implementation')  
  conflicts=(fpylll)
  provides=(fpylll)
  replaces=(fpylll)

  cd $pkgbase-$pkgver-py2 
  python2 setup.py install --skip-build --root="$pkgdir" --optimize=1
}
