# Maintainer: Felix Yan <felixonmars@archlinux.org>
# Contributor: Arch Haskell Team <arch-haskell@haskell.org>

pkgname=hledger-web
pkgver=1.15
pkgrel=3
pkgdesc="Web interface for the hledger accounting tool"
url="http://hledger.org"
license=("GPL")
arch=('x86_64')
depends=('ghc-libs' 'hledger' 'haskell-hledger-lib' 'haskell-aeson' 'haskell-blaze-html'
         'haskell-blaze-markup' 'haskell-case-insensitive' 'haskell-clientsession'
         'haskell-cmdargs' 'haskell-conduit' 'haskell-data-default' 'haskell-decimal'
         'haskell-hjsmin' 'haskell-http-conduit' 'haskell-http-client' 'haskell-http-types'
         'haskell-conduit-extra' 'haskell-safe' 'haskell-shakespeare' 'haskell-wai'
         'haskell-wai-extra' 'haskell-wai-handler-launch' 'haskell-warp' 'haskell-yesod'
         'haskell-yesod-core' 'haskell-yesod-form' 'haskell-yesod-static' 'haskell-json'
         'haskell-megaparsec')
makedepends=('ghc' 'haskell-hspec' 'haskell-yesod-test')
replaces=('hledger-api')
source=("https://hackage.haskell.org/packages/archive/${pkgname}/${pkgver}/${pkgname}-${pkgver}.tar.gz")
sha512sums=('1743835e21cf7b6c38ef31e293e0db80d1bf87dd064f382678547d2430b04f95c6d2dcf6d5175179e43f151581b239dead2400b208bd1cdda55553bafbf2ca30')

prepare() {
    cd $pkgname-$pkgver
    sed -i -e '/semigroups/d' $pkgname.cabal
}

build() {
    cd "${srcdir}/${pkgname}-${pkgver}"
    runhaskell Setup configure -O --enable-shared --enable-executable-dynamic --disable-library-vanilla \
        --prefix=/usr --docdir="/usr/share/doc/${pkgname}" --datasubdir="$pkgname" --enable-tests \
        --dynlibdir=/usr/lib --libsubdir=\$compiler/site-local/\$pkgid \
            -f-dev -f-library-only -fthreaded
    runhaskell Setup build
    runhaskell Setup register --gen-script
    runhaskell Setup unregister --gen-script
    sed -i -r -e "s|ghc-pkg.*update[^ ]* |&'--force' |" register.sh
    sed -i -r -e "s|ghc-pkg.*unregister[^ ]* |&'--force' |" unregister.sh
}

check() {
    cd $pkgname-$pkgver
    runhaskell Setup test
}

package() {
    cd "${srcdir}/${pkgname}-${pkgver}"
    install -D -m744 register.sh   "${pkgdir}/usr/share/haskell/register/${pkgname}.sh"
    install -D -m744 unregister.sh "${pkgdir}/usr/share/haskell/unregister/${pkgname}.sh"
    runhaskell Setup copy --destdir="${pkgdir}"
    rm -f "${pkgdir}/usr/share/doc/${pkgname}/LICENSE"
}
