# Maintainer: Filipe Laíns (FFY00) <lains@archlinux.org>
# Contributor: Sergej Pupykin <arch+pub@sergej.pp.ru>
# Contributor: Bartłomiej Piotrowski <bpiotrowski@archlinux.org>
# Contributor: Matthias Bauch <matthias.bauch@gmail.com>
# Contributor: Laszlo Papp <djszapi2 at gmail com>
# Contributor: Samuel Tardieu <sam@rfc1149.net>

pkgname=openocd
pkgver=0.10.0
epoch=1
pkgrel=2
pkgdesc='Debugging, in-system programming and boundary-scan testing for embedded target devices'
arch=('x86_64')
url='http://openocd.org'
license=('GPL')
depends=('libftdi' 'libftdi-compat' 'libusb' 'libusb-compat' 'hidapi')
options=(!strip)
_features=(amtjtagaccel armjtagew buspirate ftdi gw16012 jlink oocd_trace
 opendous osbdm parport presto_libftdi remote-bitbang rlink stlink ti-icdi ulink usbprog vsllink
 aice cmsis-dap dummy jtag_vpi openjtag_ftdi usb-blaster-2 usb_blaster_libftdi)
source=("https://downloads.sourceforge.net/sourceforge/$pkgname/$pkgname-$pkgver.tar.bz2")
sha512sums=('6c890c86c3339da49bd529e8674ca62bc7fce4a2a17798dcc5d70b4f7628b640d856651170a3f7e2e2a120989066e84d8439b56ff42ff2bd72446f9af0f28ba2')

prepare() {
  sed -i 's|ftdi_new();|(void*)12345;|g' $pkgname-$pkgver/configure{,.ac}
}

build() {
  cd $pkgname-$pkgver

  libtoolize
  autoreconf
  ./configure \
  	--prefix=/usr \
  	--disable-werror \
  	${_features[@]/#/--enable-}

  make
}

package() {
  cd $pkgname-$pkgver

  make DESTDIR="$pkgdir" install

  cd "$pkgdir"/usr/share/openocd/scripts/target && mv 1986*.cfg 1986be1t.cfg
}
