# Maintainer: David Runge <dave@sleepmap.de>
pkgname=padthv1
pkgver=0.9.9
pkgrel=2
pkgdesc="An old-school polyphonic additive synthesizer"
arch=('x86_64')
url="https://padthv1.sourceforge.io/"
license=('GPL2')
groups=('lv2-plugins' 'pro-audio' 'vee-one')
depends=('desktop-file-utils' 'fftw' 'hicolor-icon-theme' 'jack' 'liblo'
'qt5-base')
makedepends=('lv2' 'qt5-tools')
source=("https://download.sourceforge.net/${pkgname}/${pkgname}-${pkgver}.tar.gz"
        "${pkgname}-0.9.9-ttl.patch::https://github.com/rncbc/padthv1/commit/06ecd92.patch"
)
sha512sums=('358d70e8f6dfb622576b7b42bf150ca2c3dfa759b524748247759a8a42b3451e5e777aac2fc8c417e4b9672611d24c9066fd24e737e6ac1ecb9e31d8fe52f1c1'
            'c29e1b699a0cc90f91cc32bfef29900ae4e489bf5cec7e2eaf804ccc8bbc77d2786c0ab6994701b966282d61972eda3baf84c621b05d1e517f54dec1796b487b')

prepare() {
  cd "${pkgname}-${pkgver}"
  # TODO: Fix .ttl file
  patch -Np1 -i "../${pkgname}-0.9.9-ttl.patch"
  autoreconf -vfi
}

build() {
  cd "${pkgname}-${pkgver}"
  ./configure --prefix=/usr \
              --libdir=/usr/lib
  make
}

package() {
  cd "${pkgname}-${pkgver}"
  make DESTDIR="$pkgdir/" install
  install -t "${pkgdir}/usr/share/doc/${pkgname}" \
    -vDm 644 {AUTHORS,ChangeLog,README,TODO}
}
# vim:set ts=2 sw=2 et:
