# $Id: PKGBUILD 280539 2018-01-08 15:17:40Z foxxx0 $
# Maintainer: Thore Bödecker <foxxx0@archlinux.org>
# Contributor: Giovanni Scafora <giovanni@archlinux.org>
# Contributor: François Charette <firmicus ατ gmx δοτ net>

pkgname=perl-io-stringy
pkgver=2.111
pkgrel=3
pkgdesc="I/O on in-core objects like strings/arrays"
arch=('any')
url="https://metacpan.org/pod/IO::Stringy"
license=('GPL' 'PerlArtistic')
depends=('perl')
options=('!emptydirs')
source=("https://www.cpan.org/authors/id/D/DS/DSKOLL/IO-stringy-${pkgver}.tar.gz") 
sha512sums=('9da8fb03945bc4a59cea3b3b2e22b15d56b133470e581d1cb03920bda2b4953e3c9e4a25d095ed8a384efb5a4c58db437c92cca6a81d583791191f1a37691a4a')

build() {
  cd  "${srcdir}/IO-stringy-${pkgver}"
  PERL_MM_USE_DEFAULT=1 perl Makefile.PL INSTALLDIRS=vendor
  make
}

check() {
  cd  "${srcdir}/IO-stringy-${pkgver}"
  make test
}

package() {
  cd  "${srcdir}/IO-stringy-${pkgver}"
  make install DESTDIR="${pkgdir}"

  find ${pkgdir} -name '.packlist' -delete
  find ${pkgdir} -name '*.pod' -delete
}
