# $Id: PKGBUILD 369764 2018-08-06 08:47:28Z foutrelis $
# Maintainer: David Runge <dave@sleepmap.de>
_name=ly
pkgname=python-ly
pkgver=0.9.5
pkgrel=3
pkgdesc="Parse, manipulate or create documents in LilyPond format"
arch=('any')
url="https://github.com/wbsoft/python-ly"
license=('GPL')
depends=('python')
makedepends=('python-setuptools' 'python-sphinx')
source=("https://files.pythonhosted.org/packages/source/${pkgname::1}/${pkgname}/${pkgname}-${pkgver}.tar.gz")
md5sums=('a462a83263057291bcdb8a4d54b82b1f')
validpgpkeys=()

prepare() {
  cd "$pkgname-$pkgver"
}

build() {
  cd "$pkgname-$pkgver"
  python setup.py build
  cd doc
  make man text
}

check() {
  cd "$pkgname-$pkgver"
}

package() {
  cd "$pkgname-$pkgver"
  python setup.py install --skip-build \
    --optimize=1 \
    --root="${pkgdir}"
  # docs
  install -vDm 644 {ChangeLog,README.rst} \
    -t "${pkgdir}/usr/share/doc/${pkgname}/"
  # text readme
  install -vDm 644 doc/build/text/* \
    -t "${pkgdir}/usr/share/doc/${pkgname}/text/"
  # man pages
  install -vDm 644 doc/build/man/* \
    -t "${pkgdir}/usr/share/man/man1/"
}
