# $Id: PKGBUILD 354954 2018-07-08 14:16:40Z foutrelis $
# Maintainer: Felix Yan <felixonmars@archlinux.org>

pkgbase=python-pyte
pkgname=('python-pyte' 'python2-pyte')
pkgver=0.8.0
pkgrel=2
pkgdesc='Simple VTXXX-compatible terminal emulator'
arch=('any')
license=('LGPL3')
url='https://github.com/selectel/pyte'
makedepends=('python-setuptools' 'python2-setuptools' 'python-wcwidth' 'python2-wcwidth')
checkdepends=('python-pytest-runner' 'python2-pytest-runner')
source=("$pkgbase-$pkgver.tar.gz::https://github.com/selectel/pyte/archive/$pkgver.tar.gz")
sha512sums=('c488fd0a61c1dc34b27e12ed9ba1109bb2c331626c982da06e7540bdd168008cb5106a17c71e60e38c493f2dd9f21ba3cf05118928744dfa192d62e511b4c4e8')

prepare() {
  cp -a pyte-$pkgver{,-py2}
}

build() {
  cd "$srcdir"/pyte-$pkgver
  python setup.py build

  cd "$srcdir"/pyte-$pkgver-py2
  python2 setup.py build
}

check() {
  cd "$srcdir"/pyte-$pkgver
  python setup.py pytest

  cd "$srcdir"/pyte-$pkgver-py2
  python2 setup.py pytest
}

package_python-pyte() {
  depends=('python-wcwidth')

  cd pyte-$pkgver
  python setup.py install --root="$pkgdir" --optimize=1
}

package_python2-pyte() {
  depends=('python2-wcwidth')

  cd pyte-$pkgver-py2
  python2 setup.py install --root="$pkgdir" --optimize=1
}

# vim:set ts=2 sw=2 et:
