# Maintainer: Felix Yan <felixonmars@archlinux.org>
# Contributor: Simon Sapin <simon dot sapin at exyr dot org>
# Contributor: Kyle Keen <keenerd@gmail.com>

pkgbase=python-rencode
pkgname=(python-rencode python2-rencode)
pkgver=1.0.6
pkgrel=1
pkgdesc="A Module similar to bencode from the BitTorrent project"
url="https://github.com/aresch/rencode"
license=('GPL')
arch=('x86_64')
makedepends=('cython' 'cython2')
checkdepends=('python-pytest' 'python2-pytest')
source=("$pkgbase-$pkgver.tar.gz::https://github.com/aresch/rencode/archive/v$pkgver.tar.gz")
sha512sums=('f04de4d3a83aed916bdc4b7a8ca772655e9324d0531ee882cb7d2a1e92b397bdcec8497bf02939e0a806886ecc62ed2e7319dfee054dad1b69052157f0959e8f')

prepare() {
  cp -a rencode-$pkgver{,-py2}
}

build() {
  cd "$srcdir"/rencode-$pkgver
  python setup.py build

  cd "$srcdir"/rencode-$pkgver-py2
  python2 setup.py build
}

check() {
  cd "$srcdir"/rencode-$pkgver
  PYTHONPATH="$PWD/build/lib.linux-$CARCH-3.7" py.test

  cd "$srcdir"/rencode-$pkgver-py2
  PYTHONPATH="$PWD/build/lib.linux-$CARCH-2.7" py.test2
}

package_python-rencode() {
  depends=('python')

  cd rencode-$pkgver
  python setup.py install --root="$pkgdir" --optimize=1
}

package_python2-rencode() {
  depends=('python2')

  cd rencode-$pkgver-py2
  python2 setup.py install --root="$pkgdir" --optimize=1
}
