# $Id: PKGBUILD 348917 2018-06-30 18:14:35Z foutrelis $
# Maintainer: Felix Yan <felixonmars@archlinux.org>

pkgbase=python-sure
pkgname=("python-sure" "python2-sure")
pkgver=1.4.11
pkgrel=2
pkgdesc="An idiomatic testing library for python with powerful and flexible assertions"
arch=('any')
url="https://github.com/gabrielfalcao/sure"
license=('GPL')
makedepends=('python-six' 'python2-six' 'python-mock' 'python2-mock' 'python-setuptools'
             'python2-setuptools' 'git')
checkdepends=('python-nose' 'python2-nose')
source=("$pkgbase-$pkgver.tar.gz::https://github.com/gabrielfalcao/sure/archive/$pkgver.tar.gz")
sha512sums=('0f3601eff81074d73568014aaf81b2a3e782c95d3a62cf689031bd0c53eaa8eb531a32e4e2d16c4bee4291157f621e52857b575bcfdaf82839f8e1d0d40d3563')

prepare() {
  cp -a sure-$pkgver{,-py2}

  export LC_CTYPE=en_US.UTF-8
}

build() {
  cd "$srcdir"/sure-$pkgver
  python setup.py build

  cd "$srcdir"/sure-$pkgver-py2
  python2 setup.py build
}

check() {
  cd "$srcdir"/sure-$pkgver
  python setup.py test

  cd "$srcdir"/sure-$pkgver-py2
  python2 setup.py test
}

package_python-sure() {
  depends=('python-six' 'python-mock')

  cd sure-$pkgver
  python setup.py install --root="$pkgdir" --optimize=1
}

package_python2-sure() {
  depends=('python2-six' 'python2-mock')

  cd sure-$pkgver-py2
  python2 setup.py install --root="$pkgdir" --optimize=1
}
