# Maintainer: Morten Linderud <foxboron@archlinux.org>
# Contributor: Sergej Pupykin <pupykin.s+arch@gmail.com>
# Contributor: Jeff Mickey <jeff@archlinux.org>
# Contributor: Pappa <jcberg@gmail.com >

pkgbase=python-xlib
pkgname=('python-xlib' 'python2-xlib')
pkgver=0.25
pkgrel=1
pkgdesc="A fully functional X client library for Python programs"
url="https://github.com/python-xlib/python-xlib"
arch=('any')
license=('LGPL')
makedepends=('python2' 'python2-setuptools-scm'
             'python' 'python-setuptools-scm')
source=("$pkgname-$pkgver.tar.gz::https://github.com/python-xlib/python-xlib/archive/$pkgver.tar.gz")
sha256sums=('376498149e0ecc70a11b33882da68fc587b2f422a2b1fe0d9169fda8b566d14d')

prepare() {
  cp -a python-xlib-$pkgver{,-py2}
}

build(){
  cd "$srcdir/python-xlib-$pkgver"
  python setup.py build

  cd "$srcdir/python-xlib-$pkgver-py2"
  python2 setup.py build
}

package_python2-xlib() {
  depends=('python2' 'python2-six')

  cd "python-xlib-$pkgver-py2"
  python2 setup.py install --root="$pkgdir" --optimize=1 --skip-build
}

package_python-xlib() {
  depends=('python' 'python-six')

  cd "python-xlib-$pkgver"
  python setup.py install --root="$pkgdir" --optimize=1 --skip-build
}
