# Maintainer: Felix Yan <felixonmars@archlinux.org>
# Maintainer: Levente Polyak <anthraxx[at]archlinux[dot]org>
# Contributor: Bartosz Feński <fenio@debian.org>

pkgname=reaver
pkgver=1.6.5
pkgrel=1
pkgdesc='Brute force attack against Wifi Protected Setup'
url='https://github.com/t6x/reaver-wps-fork-t6x'
arch=('x86_64')
license=('GPL2')
depends=('glibc' 'libpcap')
source=(${pkgname}-${pkgver}.tar.gz::https://github.com/t6x/reaver-wps-fork-t6x/archive/v${pkgver}.tar.gz)
sha512sums=('3e70d9fffefee3f6d60e72d7d7b1da91032e184c7d27f94b9f26e2260b7274d491f2e41f8056b386a211b9838d21afc6b65a8a826d310b51fc1065fa9e135dc0')

prepare() {
  cd reaver-wps-fork-t6x-${pkgver}
  sed 's|CFLAGS=|CFLAGS+=|' -i src/Makefile
}

build() {
  cd reaver-wps-fork-t6x-${pkgver}/src
  ./configure --prefix=/usr --sysconfdir=/etc
  make CONFDIR=/etc/reaver
}

package() {
  cd reaver-wps-fork-t6x-${pkgver}
  install -Dm 755 src/{reaver,wash} -t "${pkgdir}"/usr/bin
  install -dm 755 "${pkgdir}"/etc/reaver
  install -Dm 644 docs/README -t "${pkgdir}"/usr/share/doc/reaver
  install -Dm 644 docs/reaver.1 -t "${pkgdir}"/usr/share/man/man1
}
