# $Id: PKGBUILD 296338 2018-02-19 08:59:53Z spupykin $
# Maintainer: Sergej Pupykin <pupykin.s+arch@gmail.com>
# Contributor: Sergej Pupykin <pupykin.s+arch@gmail.com>

pkgname=smbnetfs
pkgver=0.6.1
pkgrel=1
pkgdesc="small C program that mounts Microsoft network neighborhood in single directory."
arch=('x86_64')
url="http://smbnetfs.sourceforge.net/"
license=('GPL')
depends=('fuse2' 'smbclient')
backup=('etc/smbnetfs/.smb/smb.conf'
	'etc/smbnetfs/.smb/smbnetfs.conf'
	'etc/smbnetfs/.smb/smbnetfs.auth'
	'etc/smbnetfs/.smb/smbnetfs.host')
install=smbnetfs.install
options=(docs)
source=(https://downloads.sourceforge.net/smbnetfs/$pkgname-$pkgver.tar.bz2
	conf-smbnetfs
	smbnetfs.service)
sha256sums=('848b8ee4c1b5cc4c83ee35736cb28e1ddcd5789cca948f060e8cb76baa95380a'
            'ca3b686c37fe77193e8df86efcaadb8fe809dfaa8cd62effde6b038af07ea226'
            '9a06d4d1ffec3c2dd9bff09fa92fb3e9c0aa9569be90a61bb51f04f852b2d741')

build() {
  cd "$srcdir"/$pkgname-$pkgver
  sed -i 's|libsmbclient.h|samba-4.0/libsmbclient.h|g' \
    src/smb_conn_srv.c src/smb_conn_proto.h src/function.c src/main.c src/event.c
  [ $NOEXTRACT -eq 1 ] || ./configure --prefix=/usr --docdir=/usr/share/doc/smbnetfs --with-gnome-keyring=no
  make
}

package() {
  cd "$srcdir"/$pkgname-$pkgver

  make DESTDIR="$pkgdir" install

  mv "$pkgdir"/usr/share/doc/smbnetfs* "$pkgdir"/usr/share/doc/smbnetfs

  mkdir -p "$pkgdir"/etc/smbnetfs/.smb
  install -m0644 "$srcdir"/$pkgname-$pkgver/conf/* "$pkgdir"/etc/smbnetfs/.smb/
  install -Dm0644 "$srcdir"/$pkgname-$pkgver/README "$pkgdir"/usr/share/doc/smbnetfs/README
  install -Dm0644 "$srcdir"/conf-smbnetfs "$pkgdir"/etc/conf.d/smbnetfs
  install -Dm0644 "$srcdir"/smbnetfs.service "$pkgdir"/usr/lib/systemd/system/smbnetfs.service
  touch "$pkgdir"/etc/smbnetfs/.smb/smb.conf
}
