# Maintainer: David Runge <dave@sleepmap.de>
# Contributor: speps <speps at aur dot archlinux dot org>
# Contributor: Andreas Schnaiter <rc.poison@gmail.com>

pkgname=smtube
pkgver=19.6.0
pkgrel=1
pkgdesc="An application that allows to browse, search and play YouTube videos"
arch=('x86_64')
url="https://www.smtube.org/"
license=('GPL2')
depends=('qt5-script' 'qt5-webkit' 'hicolor-icon-theme')
makedepends=('qt5-tools')
optdepends=('mplayer: play videos with MPlayer'
            'smplayer: play videos with SMPlayer'
            'gnome-mplayer: play videos with GNOME MPlayer'
            'dragon: play videos with Dragon Player'
            'totem: play videos with Totem'
            'vlc: play videos with VLC'
            'mpv: play videos with MPV'
            'youtube-dl: download videos')
source=("https://downloads.sourceforge.net/project/${pkgname}/SMTube/${pkgver}/${pkgname}-${pkgver}.tar.bz2")
sha512sums=('f61e432b8f99e34ddbd9415064eecf30c9a3a6731d646073253d63690cf531321a7a5038117db981d036d1abfdbd3150df21bc22c9ae75e32c63ade3a859ecef')

build() {
  cd "${pkgname}-${pkgver}"
  make PREFIX=/usr
}

package() {
  cd "${pkgname}-${pkgver}"
  make PREFIX=/usr DESTDIR="${pkgdir}/" install
}
