# Maintainer : Christian Rebischke <Chris.Rebischke@archlinux.org>
# Contributor: Frederik "Freso" S. Olesen <archlinux@freso.dk>
# Contributor: Bastien Traverse <firstname at lastname dot email>
# Contributor: Samantha Baldwin <fuhsaz+git@cryptic.li>
# Contributor: Caleb Reach <jtxx000@gmail.com>
# Contributor: Felix Yan <felixonmars@gmail.com>
# Contributor: Karol "Kenji Takahashi" Woźniak <kenji.sx>
# Contributor: Mantas Mikulėnas <grawity@gmail.com>

pkgname=whipper
pkgver=0.7.3
pkgrel=1
pkgdesc="A Unix CD ripper aiming for accuracy over speed -- forked from morituri"
arch=('any')
url="https://github.com/whipper-team/whipper"
license=('GPL3')
depends=(
    'accuraterip-checksum'          # for accuraterip-checksum calculation
    'libcdio-paranoia'              # for the actual ripping
    'cdrdao'                        # for session, TOC, pregap, and ISRC extraction
    'libsndfile'                    # for reading wav files (pulls in flac, also required for reading flac files)
    'mutagen'                       # for metadata handling
    'python2-musicbrainzngs'        # for metadata lookup
    'python2-pycdio'                # for storing drive identification in config file
    'python2-setuptools'            # for plugin support
    'sox'                           # for track peak detection'
    'python2-gobject2'              # Bugfix FS#54074
    'python2-requests'
    )
checkdepends=(
    'python2-twisted'
    )
conflicts=('morituri')
source=("${pkgname}-v${pkgver}.tar.gz::${url}/archive/v${pkgver}.tar.gz")
sha512sums=('ac96393471a6b4c40f5870f6e3183b65d43229314e2a1eacbf065c51ac61cbc772f2de3bde9f20ee1f7ffec427cd03c31f27df60eb6c621a699927646080c0ab')

check() {
    cd "$srcdir/${pkgname}-${pkgver}"
    python2 -m unittest discover
}

package() {
    cd "$srcdir/${pkgname}-${pkgver}"
    python2 setup.py install --root="${pkgdir}"/ --optimize=1
}
