# $Id: PKGBUILD 309577 2017-11-12 00:10:08Z heftig $
# Maintainer: Jan Alexander Steffens (heftig) <jan.steffens@gmail.com>
# Contributor: Jaroslav Lichtblau <dragonlord@aur.archlinux.org>
# Contributor: Jeremy Cowgar <jeremy@cowgar.com>

pkgname=check
pkgver=0.12.0
pkgrel=1
pkgdesc="A unit testing framework for C"
url="https://libcheck.github.io/check/"
arch=(i686 x86_64)
license=(LGPL)
depends=(awk)
makedepends=(git)
_commit=673dce1d61781c32b449bef0ee8711dc7e689170  # tags/0.12.0
source=("git+https://github.com/libcheck/check#commit=$_commit")
md5sums=('SKIP')

pkgver() {
  cd $pkgname
  git describe --tags | sed 's/-/+/g'
}

prepare() {
  cd $pkgname
  autoreconf -fvi
}

build() {
  cd $pkgname
  ./configure --prefix=/usr --disable-static
  make
}

check() {
  cd $pkgname
  # Extremely long
  #make -k check
}

package() {
  cd $pkgname
  make DESTDIR="$pkgdir" install

  # get rid of the package's info directory
  rm "$pkgdir/usr/share/info/dir"

  # svn log file is too big
  rm "$pkgdir"/usr/share/doc/check/*ChangeLog*
}
