# Maintainer: Jan Alexander Steffens (heftig) <jan.steffens@gmail.com>

pkgname=dleyna-renderer
pkgver=0.6.0
pkgrel=3
pkgdesc="Library to discover and manipulate Digital Media Renderers"
arch=(x86_64)
url="http://01.org/dleyna"
license=(LGPL2.1)
depends=(dleyna-connector-dbus gupnp-av gupnp-dlna libsoup)
makedepends=(git)
_commit=334baba53e253957637b86764347dcc27cf091ab  # tags/0.6.0
source=("git+https://github.com/01org/dleyna-renderer#commit=$_commit"
        gupnp-1.2.diff)
sha256sums=('SKIP'
            '0c9718176c3067c8dd920c24c19b79692d869e49632ac42ee69b796bc5eef954')

pkgver() {
  cd $pkgname
  git describe --tags | sed 's/-/+/g'
}

prepare() {
  cd $pkgname
  patch -Np1 -i ../gupnp-1.2.diff
  NOCONFIGURE=1 ./autogen.sh
}

build() {
  cd $pkgname
  CFLAGS+=" -Wno-deprecated-declarations"
  ./configure --prefix=/usr --sysconfdir=/etc --localstatedir=/var \
    --disable-static --libexecdir=/usr/lib
  sed -i -e 's/ -shared / -Wl,-O1,--as-needed\0/g' libtool
  make
}

check() {
  cd $pkgname
  make check
}

package() {
  cd $pkgname
  make DESTDIR="$pkgdir" install
}
