# $Id: PKGBUILD 321007 2018-04-05 22:49:36Z jgc $
# Maintainer: Jan de Groot <jgc@archlinux.org>
# Contributor: Tom Newsom <Jeepster@gmx.co.uk>
# Contributor: Juergen Hoetzel <juergen@archlinux.org>

pkgname=neon
pkgver=0.30.2
pkgrel=3
pkgdesc="HTTP and WebDAV client library with a C interface"
arch=('x86_64')
url="https://web.archive.org/web/20170928175008/http://www.webdav.org/neon/"
license=('GPL' 'LGPL')
depends=('krb5' 'expat' 'ca-certificates' 'zlib')
options=('libtool') # FS#16067
source=(https://fossies.org/linux/www/${pkgname}-${pkgver}.tar.gz
        $pkgname-$pkgver.tar.gz.asc)
sha1sums=('d1c020f96731135263476ebaa72b2da07c4727cd'
          'SKIP')
validpgpkeys=('190555472DCC589BEF01609C608A86DF9833CC49') # Joe Orton

build() {
  cd "${srcdir}"/${pkgname}-${pkgver}
  ./configure --prefix=/usr \
    --with-expat \
    --enable-shared \
    --disable-static \
    --with-ssl=openssl \
    --with-ca-bundle=/etc/ssl/certs/ca-certificates.crt
  sed -i -e 's/ -shared / -Wl,-O1,--as-needed\0/g' libtool
  make
}

package() {
  cd "${srcdir}"/${pkgname}-${pkgver}
  make DESTDIR="${pkgdir}" install
}
