# Maintainer: Levente Polyak <anthraxx[at]archlinux[dot]org>
# Contributor: Étienne Deparis <etienne@depar.is>
# Contributor: Christoph J. Thompson <thompsonc@protonmail.ch>

pkgname=nitrokey-app
pkgver=1.4
pkgrel=1
pkgdesc='Nitrokey management application'
url='https://www.nitrokey.com'
arch=('x86_64')
license=('GPL3')
depends=('qt5-base' 'qt5-svg' 'hicolor-icon-theme' 'libnitrokey' 'libnitrokey.so')
makedepends=('cmake' 'qt5-tools' 'bash-completion' 'cppcodec')
source=(https://github.com/Nitrokey/nitrokey-app/releases/download/v${pkgver}/nitrokey-app-v${pkgver}.tar.gz{,.sig})
sha512sums=('b7565a44941e4dfdc8f225971fade4e83beabacac8271528393a63ccc074ba0d4a7b9d050e5c9f40087006ba21115aeccf11a48b807309e55e49b3f427b593c9'
            'SKIP')
validpgpkeys=('868184069239FF65DE0BCD7DD9BAE35991DE5B22') # Szczepan Zalega <szczepan.zalega@gmail.com>

prepare() {
  cd ${pkgname}-v${pkgver}
  mkdir -p build
  rm -r data/icons/ubuntu-mono-{dark,light} 3rdparty/cppcodec
  ln -s /usr/include/cppcodec 3rdparty/cppcodec
}

build() {
  cd ${pkgname}-v${pkgver}/build
  cmake .. \
        -DCMAKE_BUILD_TYPE=Release \
        -DBUILD_SHARED_LIBS=ON \
        -DCMAKE_INSTALL_PREFIX=/usr
  make
}

package() {
  cd ${pkgname}-v${pkgver}
  make -C build DESTDIR="${pkgdir}" install
}

# vim: ts=2 sw=2 et:
