# Maintainer: Florian Pritz <bluewind@xinu.at>

pkgname=perl-crypt-openssl-guess
pkgver=0.11
pkgrel=3
pkgdesc='Guess OpenSSL include path'
arch=(any)
license=(PerlArtistic GPL)
options=(!emptydirs)
depends=('perl>=5.8.1')
makedepends=('perl-extutils-makemaker>=6.64')
url=https://metacpan.org/release/Crypt-OpenSSL-Guess
source=("http://search.cpan.org/CPAN/authors/id/A/AK/AKIYM/Crypt-OpenSSL-Guess-$pkgver.tar.gz")
md5sums=(e768fe2c07826b0ac9ea604c79f93032)
sha512sums=(cdae7f20a15d24842cf117bfba4f3bc0ec7d1066251e0480cbadd8f0aa28c9c9573905726fc1333ea9fbbb3769a67dbf28043de8487dcce27dab5d14a0848b09)
_ddir="Crypt-OpenSSL-Guess-$pkgver"

build()
(
  cd "$srcdir/$_ddir"
  export PERL_MM_USE_DEFAULT=1 PERL_AUTOINSTALL=--skipdeps
  unset PERL5LIB PERL_MM_OPT
  /usr/bin/perl Makefile.PL
  make
)

check()
(
  cd "$srcdir/$_ddir"
  export PERL_MM_USE_DEFAULT=1
  unset PERL5LIB
  make test
)

package()
(
  cd "$srcdir/$_ddir"
  make install INSTALLDIRS=vendor DESTDIR="$pkgdir"
  find "$pkgdir" -name .packlist -o -name perllocal.pod -delete
)

# Local Variables:
# mode: shell-script
# sh-basic-offset: 2
# End:
# vim:set ts=2 sw=2 et:
