# Maintainer:
# Contributor: Stanislaw Datskevich <me a nek0 net>
# Contributor: Gregor Robinson <gregor@fiatflux.co.uk>
# Contributor: Martin Perner <martin dot perner at gmail dot com>

pkgname=pkcs11-helper
pkgver=1.25.1
pkgrel=1
pkgdesc="A library that simplifies the interaction with PKCS11 providers for end-user applications using a simple API and optional OpenSSL engine"
arch=('x86_64')
url='https://github.com/OpenSC/pkcs11-helper'
license=(GPL BSD)
depends=('gnutls' 'nss' 'openssl')
source=("https://github.com/OpenSC/pkcs11-helper/archive/pkcs11-helper-$pkgver.tar.gz")
sha512sums=('d9e7d63747529a0af21eb18c822ec23c25f613dfa2a9c7bcdc1749e70ec4f6aa6ffd1a2ab731e2cbaaf576a6a0e612923a15cace79dc6119b1ef4fd7ac79f269')

build() {
  cd pkcs11-helper-pkcs11-helper-$pkgver
  libtoolize
  aclocal
  autoheader
  automake --add-missing
  autoreconf -v
  ./configure --prefix=/usr
  make
}

package() {
  cd pkcs11-helper-pkcs11-helper-$pkgver
  make DESTDIR="$pkgdir" install
  mkdir -p "$pkgdir"/usr/share/licenses/$pkgname/
  install -Dm644 COPYING* "$pkgdir"/usr/share/licenses/$pkgname/
}

